 # Copyright 2010-2011 Fredrik Wikstrom. All rights reserved.
 #
 # Redistribution and use in source and binary forms, with or without
 # modification, are permitted provided that the following conditions
 # are met:
 #
 # 1. Redistributions of source code must retain the above copyright
 #    notice, this list of conditions and the following disclaimer.
 #
 # 2. Redistributions in binary form must reproduce the above copyright
 #    notice, this list of conditions and the following disclaimer in the
 #    documentation and/or other materials provided with the distribution.
 #
 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS `AS IS'
 # AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 # ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
 # LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
 # CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
 # SUBSTITUTE GOODS OR SERVICES# LOSS OF USE, DATA, OR PROFITS# OR BUSINESS
 # INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
 # CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 # ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
 # POSSIBILITY OF SUCH DAMAGE.
 #

	.text
	.align 2
	.global swab2
swab2:
	subi	r1,r1,4
	stw		r13,0(r1)

	andi.	r6,r5,15
	srwi.	r5,r5,4
	subi	r3,r3,4
	subi	r4,r4,16
	li		r11,4
	li		r12,8
	li		r13,12
	beq-	skip_loop1

	mtctr	r5
loop1:
	lwz		r7,4(r3)
	lwz		r8,8(r3)
	lwz		r9,12(r3)
	lwzu	r10,16(r3)
	
	addi	r4,r4,16
	
	rlwinm	r7,r7,16,0,31
	rlwinm	r8,r8,16,0,31
	rlwinm	r9,r9,16,0,31
	rlwinm	r10,r10,16,0,31
	
	stwbrx	r7,0,r4
	stwbrx	r8,r11,r4
	stwbrx	r9,r12,r4
	stwbrx	r10,r13,r4
	bdnz+	loop1
	
skip_loop1:
	srwi.	r6,r6,1
	addi	r3,r3,2
	addi	r4,r4,14
	beq-	skip_loop2

	mtctr	r6
loop2:
	addi	r4,r4,2
	lhzu	r7,2(r3)
	sthbrx	r7,0,r4
	bdnz+	loop2

skip_loop2:
	lwz		r13,0(r1)
	addi	r1,r1,4
	blr
